18-07-2005, 19:37
|
|
|
|
חבר מתאריך: 18.07.05
הודעות: 5
|
|
זהו שאני לא מצליח להכניס את הקוד הזה לדף ה- ASP שלי,
להלן הקוד אם תוכלו לעזור..
<%@Language=VBScript codepage=1255%>
<%
'************************************************* ************************
'************************************************* ************************
Option explicit
Response.Buffer = true
%>
<!--#include file="../UserMods/_INClanguage_.asp"-->
<!--#include file="_INCconfig_.asp"-->
<!--#include file="_INCappDBConn_.asp"-->
<!--#include file="_INCappFunctions_.asp"-->
<%
'Database
dim mySQL
dim conntemp
dim rstemp
dim rstemp2
'Session
dim idOrder
dim idCust
'************************************************* ************************
'Open Database Connection
call openDB()
'Store Configuration
if loadConfig() = false then
call errorDB(langErrConfig,"")
end if
'Get/Set Cart/Order Session
idOrder = sessionCart()
'Get/Set Customer Session
idCust = sessionCust()
'Get/Set Affilate ID
call getIdAffiliate(Request.QueryString("idAff"))
%>
<!--#include file="../UserMods/_INCtemplate_.asp"-->
<%
'Close Database Connection
call closeDB()
'************************************************* *********************
'Main Shopping Cart Display Area.
'************************************************* *********************
sub cartMain()
%>
<table border=0 cellspacing=0 cellpadding=0 width="100%">
<tr>
<td align=left valign=top width="100%">
<table border=0 cellpadding=5 cellspacing=0 width="100%">
<%
'Get Featured Products
mySQL="SELECT idProduct,description,descriptionLong," _
& " listPrice,price,smallImageUrl,stock," _
& " fileName,noShipCharge,sortOrder " _
& "FROM products " _
& "WHERE active = -1 " _
& "AND homePage = -1 " _
& "ORDER BY sortOrder ASC,idProduct DESC "
set rsTemp = openRSopen(mySQL,adUseClient,adOpenStatic,adLockOp timistic,adCmdText,0)
'Randomize the recordset
if homeViewRandom > 0 and rsTemp.RecordCount > 2 then
'Disconnect recordset and initialize random seed
set rsTemp.ActiveConnection = nothing
randomize()
'Update sortOrder field with random numbers and sort
do while not rsTemp.EOF
rsTemp.Update "sortOrder",Int((9999 * Rnd) + 1)
rsTemp.MoveNext
loop
rsTemp.Sort = "sortOrder"
'Delete any extra records from disconnected recordset
rsTemp.move homeViewRandom,1
do while not rsTemp.EOF
rsTemp.Delete
rsTemp.MoveNext
loop
'Reposition to first record
rsTemp.MoveFirst
end if
'If Featured Products = 0 then use "_INCright_.asp"
if rsTemp.EOF then
call noProd()
else
'If Featured Products <= 2 then display single rows
if rsTemp.RecordCount <= 2 then
do while not rsTemp.EOF
call singleProd()
if not rsTemp.EOF then
rsTemp.MoveNext
end if
loop
'If Featured Products > 2 then display double rows
else
do while not rsTemp.EOF
call doubleProd()
if not rsTemp.EOF then
rsTemp.MoveNext
end if
loop
end if
end if
%>
</table>
</td>
</tr>
</table>
<%
end sub
'************************************************* *********************
'Displayed when there are no Featured Products.
'************************************************* *********************
sub noProd()
%>
<tr>
<td align=center valign=top>
<!--#include file="../UserMods/_INCright_.asp"-->
</td>
</tr>
<%
end sub
'************************************************* *********************
'Displays ONE Featured Product across the width of a row.
'************************************************* *********************
sub singleProd()
%>
<tr>
<td nowrap align=center valign=top class="CPhomeImg">
<%call prodImage()%>
</td>
<td align=left valign=top class="CPhomeDesc">
<%call prodDetail()%>
</td>
</tr>
<tr><td colspan=2><img src="../UserMods/misc_cleardot.gif" height=1 width=1></td></tr>
<%
end sub
'************************************************* *********************
'Displays TWO Featured Products across the width of a row.
'************************************************* *********************
sub doubleProd()
%>
<tr>
<td valign=top class="CPhomeDesc" style="width:50%"><div align="right">
<%call prodDetail()%>
</td>
<td nowrap valign=top align=center class="CPhomeImg">
<%call prodImage()%>
</td>
<td style="width:1px"><img src="../UserMods/misc_cleardot.gif" height=1 width=1></td>
<%
rsTemp.MoveNext
if rsTemp.EOF then %>
<td> </td><td> </td>
<% exit sub
end if
%>
<td valign=top class="CPhomeDesc" style="width:50%"><div align="right">
<%call prodDetail()%>
</td>
<td nowrap valign=top align=center class="CPhomeImg">
<%call prodImage()%>
</td>
</tr>
<tr><td colspan=5><img src="../UserMods/misc_cleardot.gif" height=1 width=1></td></tr>
<%
end sub
'************************************************* *********************
'Writes the product detail
'************************************************* *********************
sub prodDetail()
%>
<b class="CPprodDesc"><%=rsTemp("description")%></b><br><br>
<span class="CPprodDescLong"><%=trim(rsTemp("descriptionLong"))%></span><br><br>
<%
'Show pricing if required for this product
if not(pHidePricingZero=-1 and rsTemp("Price")=0) then
'Assign pricing info to local variables for easier use.
dim listPrice, price
listPrice = rsTemp("listPrice")
price = rsTemp("price")
'Show Extended layout.
if homeViewLayout = 1 then
if listPrice > Price then %>
<span class=CPprodLPriceT><%=langGenListPrice%>:</span> <del class=CPprodLPriceV><%=pCurrencySign & moneyS((listPrice))%></del><br>
<% end if %>
<b class=CPprodPriceT><%=langGenOurPrice%>:</b> <b class=CPprodPriceV><%=pCurrencySign & moneyS(Price)%></b>
<% if (listPrice - Price) > 0 then %>
<br><span class=CPprodSPriceT><%=langGenYouSave%>:</span> <span class=CPprodSPriceV><%=pCurrencySign & moneyS((listPrice-Price))%> (<%=formatNumber((((listPrice-Price)/listPrice)*100),0)%>%)</span>
<% end if
'Show Classic layout.
else %>
<b class=CPprodPriceT><%=langGenOurPrice%>:</b> <b class=CPprodPriceV><%=pCurrencySign & moneyS(Price)%></b>
<% end if %>
<br><br>
<%
end if
'Show Extended layout.
if homeViewLayout = 1 then
'Free Shipping?
if UCase(rsTemp("noShipCharge")) = "Y" and len(trim(rsTemp("fileName")&"")) = 0 then %>
<b class=CPfreeShipMsg><%=langGenFreeShipping%></b><br>
<% end if
'In stock, Out of stock
if pShowStockView = -1 then
if pHideAddStockLevel = -1 then %>
<b class=CPinStock><%=langGenInStock%></b><br>
<% else
if rsTemp("stock") > pHideAddStockLevel then %>
<b class=CPinStock><%=langGenInStock%></b><br>
<% else %>
<b class=CPoutStock><%=langGenOutStock%></b><br>
<% end if
end if
end if
end if
end sub
'************************************************* *********************
'Writes the code to display the product image and a link
'************************************************* *********************
sub prodImage()
if len(trim(rsTemp("smallImageUrl")&"")) <> 0 then %>
<a href="prodView.asp?idproduct=<%=rsTemp("idProduct")%>"><img src="<%=pImagesDir & rsTemp("smallImageUrl")%>" border=0 alt="<%=server.HTMLEncode(rsTemp("description"))%>"></a><br>
<% else %>
<br><b class="CPnoImgT"><%=langGenNoImage%></b><br>
<% end if %>
<br><a href="prodView.asp?idproduct=<%=rsTemp("idProduct")%>"><%=langGenViewMore%></a><br>
<%
end sub
%>
|
ראשי
צ'אט
מצב כלאיים
